home *** CD-ROM | disk | FTP | other *** search
/ Mac Magazin/MacEasy 32 / Mac Magazin and MacEasy Magazine CD - Issue 32.iso / Grafik & Text / OzTeX3.0 / Metafont / Inputs / ec / exitalp.mf < prev    next >
Text File  |  1997-03-16  |  4KB  |  94 lines
  1. % exitalp.mf
  2. %
  3. % (c) Copyright 1995, 1996, 1997 J"org Knappen
  4. % (c) Copyright 1990, 1992 Norbert Schwarz
  5. %
  6. % This file is part of ecfonts version 1.0
  7. %
  8. % Please read the files 00readme.txt, 00inst.txt, 00error.txt, and
  9. % copyrite.txt for further information
  10. %
  11. % You find some documentation in ecdoc.tex (needs LaTeX2e)
  12. %
  13. % Content:
  14. %
  15. % italic special characters  &, ?, spanish ? which are
  16. %  different from roman
  17.  
  18. version_check(1,0);  % |version_check| was introduced in dc1.3
  19.  
  20. ecchar "Italic ampersand";
  21. beginchar("&",14u#,asc_height#,0);
  22. italcorr asc_height#*slant-1.5u#;
  23. adjust_fit(if monospace:-u#,-2u# else: 0,0 fi); pickup fine.nib;
  24. pos1(flare,0); pos2(hair,0); pos3(vair,90);
  25. rt x2r=hround.5w; x3=1/3(w-u);
  26. top y3r=h+o; y2=.5[x_height,h]; bulb(3,2,1);  % left bulb
  27. pos4(stem,180); pos5(vair,270); pos6(hair,360); pos7(vair,450);
  28. pos8(curve,540); pos9(vair,630); pos10(hair,720);
  29. lft x4r=hround 1.25u; x5=x7=x3+1/6u; rt x6r=hround(x5+1.5u);
  30. lft x8r=hround u; x9=.5w; rt x10r=hround(w-1.5u);
  31. y4=.5[y3,y5]; top y5l=vround .77x_height; y6=.5[y5,y7];
  32. y7l=good.y 1/3[y5,y3]; y8=.5[y7,y9]; bot y9r=-o; y10=bar_height;
  33. pos12(hair,0); pos13(curve,0); pos14(hair,0); pos15(vair,90); pos16(curve,90);
  34. rt x12r=rt x13r=hround(w-2u); lft x14l=hround(.5w+.5u);
  35. x15=x16=rt x14r+u;
  36. y12=y13=h-.5curve; y14=.5[bar_height,x_height];
  37. bot y15l=bot y16l=vround y10;
  38. numeric theta; theta=angle((z12-z14)xscaled 2);
  39. pos11(hair,theta); x11=w-4u; y11=.5[y13,y16];
  40. filldraw stroke pulled_arc.e(3,4) & pulled_arc.e(4,5) & pulled_arc.e(5,6)
  41.  & pulled_arc.e(6,7) & pulled_arc.e(7,8) & pulled_arc.e(8,9)
  42.  & {{interim superness:=more_super; pulled_arc.e(9,10)}}
  43.  ..tension .9 and 1..{dir(theta+100)}z11e;  % bowls, loop, and stem
  44. pos11'(hair,theta-90); z11'=z11;
  45. forsuffixes $=l,r: path p$;
  46.  p$=z12${down}..z11'${-dir theta}..{down}z14$...{right}z15$; endfor
  47. filldraw p.l--reverse p.r--cycle;  % arms
  48. path q[]; q1=z13r{up}..z13l{down}..cycle;
  49. q2=z16l{right}..z16r{left}..cycle;
  50. filldraw subpath(0,ypart(p.l intersectiontimes q1)) of q1--cycle; % upper bulb
  51. filldraw subpath(0,ypart(p.r intersectiontimes q2)) of q2--cycle; % lower bulb
  52. penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16); endchar;
  53.  
  54. ecchar "Italic question mark";
  55. beginchar("?",9u#,asc_height#,0);
  56. italcorr asc_height#*slant-u#;
  57. adjust_fit(0,0); pickup tiny.nib; pos10(dot_size,0); pos11(dot_size,90);
  58. lft x10l=hround(.5w-.5dot_size); bot y11l=0; z10=z11; dot(10,11);  % dot
  59. pickup fine.nib; pos1(flare,180); pos2(hair,180); pos3(vair,90);
  60. lft x1r=hround u; x3=.5w;
  61. y1-.5flare=x_height; top y3r=h+o; bulb(3,2,1); % bulb
  62. pos8(vair,-90); x8=.5w; bot y8r=.25[top y11r,x_height]+1;
  63. numeric theta; theta=90+angle(10u,y3-y8); slope:=(y3-y8)/10u;
  64. pos3'(vair,-90); z3'=z3; pos0(vstem,theta); x0=x3; y0=1/3[y8,y3];
  65. rt x4l=hround(w-1.5u); lft x7r=hround 1/3w;
  66. x4l-x4r=x7l-x7r=hround .5[vair,vstem]-fine;
  67. ellipse_set(3'l,4l,5l,0l); ellipse_set(3'r,4r,5r,0r); y4=y4r;
  68. ellipse_set(8l,7l,6l,0l); ellipse_set(8r,7r,6r,0r); y7=y7r;
  69. pos9(hair,0); rt x9r=hround(2/3w+.5hair); y9=good.y .5[y8,y0];
  70. filldraw stroke super_arc.e(3',4) & z4e{down}
  71.  ..z5e---z6e..z7e{down} & super_arc.e(7,8)...{up}z9e;  % main stroke
  72. penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
  73.  
  74. ecchar "Spanish open italic question mark";
  75. beginchar(oct"276",9u#,asc_height#-desc_depth#,desc_depth#);
  76. adjust_fit(0,0); pickup tiny.nib; pos10(dot_size,0); pos11(dot_size,90);
  77. lft x10l=hround(.5w-.5dot_size); top y11r=h; z10=z11; dot(10,11);  % dot
  78. pickup fine.nib; pos1(flare,0); pos2(hair,0); pos3(vair,-90);
  79. rt x1r=hround(w-u); x3=.5w; y1+.5flare=asc_height-x_height-d;
  80. bot y3r=-d-o; bulb(3,2,1); % bulb
  81. pos8(vair,90); x8=.5w; top y8r=.25[bot y11l,y1+.5flare]-1;
  82. numeric theta; theta=angle(10u,y8-y3)-90; slope:=(y8-y3)/10u;
  83. pos3'(vair,90); z3'=z3; pos0(vstem,theta); x0=x3; y0=1/3[y8,y3];
  84. lft x4l=hround 1.5u; rt x7r=hround 2/3w;
  85. x4r-x4l=x7r-x7l=hround .5[vair,vstem]-fine;
  86. ellipse_set(3'l,4l,5l,0l); ellipse_set(3'r,4r,5r,0r); y4=y4r;
  87. ellipse_set(8l,7l,6l,0l); ellipse_set(8r,7r,6r,0r); y7=y7r;
  88. pos9(hair,180); lft x9r=hround(1/3w-.5hair); y9=good.y .5[y8,y0];
  89. filldraw stroke super_arc.e(3',4) & z4e{up}
  90.  ..z5e---z6e..z7e{up} & super_arc.e(7,8)...{down}z9e;  % main stroke
  91. penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
  92.  
  93. endinput;
  94.